Shareware Grab Bag/Shareware Grab Bag.iso/001/zcomm1.arc/PHODIR.T

Text File | 1986-10-22 | 14.8 KB | 442 lines

rev 10-14-86 for ZCOMM
ak    lput "\r\n\E[1;5mType space to Continue\E[m"; if y
    lput "\E[2A\E[2K"
busy    speed 1200 putw "ATM0H1\r"
reset    speed 1200; putw "ATZ\r";pat 1 OK; wait -f3
twx    if twxout speed 1200 %s8 f -qxh twxout;o
    else echo " No file to Send. "
tryd    %telno
dial    pat; pat 0 K\r\n; ena -d
    if c bye
    put "ATZ\r"; wait -f3; if !0 wait -f3
    if !0 echo "A Maxwell Perhaps?"; sleep 60; put "ATZ\r"; wait -f5
    if !0 put "AT E1 Q0 V1\r"; wait -f3
    if "!0&&S>1201" speed 1200 put "ATZ\r"; wait -f3; if !0 wait -f3
    if "!0&&S>301" speed 300 put "ATZ\r"; wait -f3; if !0 wait -f3
    if !0 put "AT E1 Q0 V1\r"; wait -f3
    if !0 echo "No response From MODEM"; pat; fail
    sleep 4
    put "ATS6=5 S8=4 S0=0\r" wait -f2
    pat 1 CONNECT; pat 2 "NO CARRIER"; pat 3 "BUSY"; pat 4 RING;
    pat 0c ";"
    dis -d
    put %mprefix; putw %telno\r
    if 0 wait -f30; echo "Hit SPACE to Hang Up"; return
    wait -f60
    while "4&&!L>3" wait -f20
    if 1 pat; return
    pat; fail
askspd    lput "1200 baud?"; if y sp 1200; return
    lput "2400 baud?"; if y sp 2400; return
    lput "4800 baud?"; if y sp 4800; return
    lput "9600 baud?"; if y sp 9600; return
    lput "19200 baud?"; if y sp 19200; return
    lput "300 baud then."; sp 300; return
callcis    speed 1200
    if %s3 sets telno %s3; gosub tryd; if c sleep 20 put \3 return
    speed 300
    if %s2 sets telno %s2; gosub tryd; if c sleep 20 put \3 return
    sp 1200
    if %s5 sets telno %s5; gosub tryd; if c gosub tym12; return
    if %s4 sets telno %s4; gosub tryd; if c gosub tel12; return
    echo "Sorry, none of the numbers are working right now"
    gosub ak
    fail
tel12    pat 1 TERMINAL
    while "c&&!1" put "\r" wait -f2
    if !c fail
    pat 1 @
    put "D1\r"; wait -f40
    if !c fail
    if !1 o fail
    put "C 202202\r"
    return
tym24    wait -f5
    in !c fail
    put A pat 1 "log in"; wait
    put "%s1\r"; return
tym12    pat 1 x; wait
    if !c fail
    put A pat 1 "log in"; wait
    if !c fail
    put "%s1\r"; return
setup    echo "Running ..."
    if dg>10000 return
    if da>1 goto setu1
    if !flocal.t gosub sinit; gosub .local.t; goto setu1
    gosub .local.t
    echo "Hello %s6 %s7."
    lput "Has your phone number info changed since the\r\n"
    lput "last time you entered your name (y/n) ?"
    if y del local.t; gosub sinit; gosub .local.t
setu1:    set mcommand "gosub dial"; set s9 ""
    if du goto setu3
    set s9 "1"
    pd1; pz480
    pe0; lput "Checking COM1 ..."; port 1; if e pe0; port 2; set s9 "2"; goto cm1
    if c echo " I Detect CARRIER on COM1. "; gosub carrier; if is9,x goto setu3
    if is9,y goto cm2
    sp 300 mput "ATZ\r" sleep 4 pe0; if !m put "AT E1 Q0 V1\r"; sleep 6; pe0
    if m goto setu3
    if !m pe0; lput "Checking COM2 ..."; port 2; set s9 "2";if e goto cm3
cm1:    if c echo " I Detect CARRIER on COM2. "; gosub carrier; if %s9 goto setu3
cm2:    if !c sp 300 mput "ATZ\r" sleep 4; if !m put "AT E1 Q0 V1\r"; sleep 6
    pe0
cm3:    if "!c&&!m||e" echo "WARNING: No Modem detected on Port 1 or 2!"; port 1
setu3:    pe0
    set f3 @rb;  set f4 "@kermit rb"
    set f5 "@accept s1 Send-File(s): sz %s1"
    set f6 "@accept s2 Receive-File: rc %s2"
    set f7 "@accept s1 Send-File: sx %s1"
    set f8 "\PXXXXX"
    set f11 "@find speed %phones"
    set f12 "@accept s1 Name:; find \n%s1 %phones"
    set f13 "@find \\\;\r %phones"
    set f14 "@speed 1200 putw ATH\r"
    if fyamhelp.t set helpfile "yamhelp.t"; set f10 "@help"
    if f/zmanh.hlp set helpfile "@yhp /zmanh.hlp"; set f10 "@help"
    if fzmanh.hlp set helpfile "@yhp zmanh.hlp"; set f10 "@help"
    if da>1 return
    : return : uncomment this line to remove automatic menu startup
    cls; goto cmdch
demo    cls
    goto cmdch
badcmd: cls echo "Unknown Command"
cmdch:    echo " ZCOMM Beginner's Menu "
    display nlmode nooverstrike
    lput "\nc  Compuserve Online Demo (requires modem)\n"
    lput "d  Dial telephone number and connect\n"
    lput "f  Flash-up HELP Processor\n"
    lput "g  Go Local (Direct Connection)\n"
    lput "h  Host Operation demo (dial-in)\n"
    lput "l  List file names in current directory\n"
    lput "n  Newest files listed first\n"
    lput "o  Display Ordering Information\n"
    lput "r  Review (circular buffer search/cut/paste) demo\n"
    lput "t  Call Telegodzilla (Omen's Software Downloading System)\n"
    lput "u  Utility command demo\n"
    lput "v  Voice call to Omen Technology (requires modem)\n"
    lput "x  eXit to DOS\n"
    lput "z  exit to ZCOMM command prompt\n\n"
choos:    acceptl1 s1 "Please enter your menu choice "
    if is1,c call cidemo; cls; goto cmdch
    if is1,d call xdnum; cls; goto cmdch
    if is1,f help; goto cmdch
    if is1,g call glocal; cls; goto cmdch
    if is1,h gosub host; host; return
    if is1,l dirr; goto choos
    if is1,n dirt; goto choos
    if is1,o gosub order; goto choos
    if is1,r kill; gosub review; goto choos
    if is1,t call telegodzilla; cls; goto cmdch
    if is1,u gosub udemo; cls; goto cmdch
    if is1,v call caf; if y||df putw "ATZ\r"; goto choos
    if is1,x x
    if is1,y goto quitt
    if is1,z goto quitt
    goto badcmd
udemo:    cls;  echo "Enabling debug output to show the commands"; pv4
    echo "The find command searches files for a string, case insensitive"
    find zcom *.t
    gosub ak
    echo "The sum command calculates file checksum compatible with Unix"
    sum local.t
    gosub ak
    echo "Word Count: lines, words, printing characters, and characters"
    echo "The count of printing characters predicts ribbon usage!"
    wc *.t
    gosub ak
    echo "The chek command calculates a 16 bit file CRC useful for comparing"
    echo "Multiple copies of the same file for accurcacy and identity."
    chek local.t
    gosub ak
    cls
    echo "Paced upload transmission demonstration"
    echo "File Upload pacing is used with bulletin boards, etc."
    echo "Note the EXTRA delay at the end of each line"
    display nooverstrike
    open %phones
    echo "Let's just send a little bit from the END of the file"
    seek -120
    ph2; o; t -adhxtp
    close; pv0; dis -dah
    gosub ak
    return

73    speed 1200 %l-603-924-9809 t
amrad-bbs    speed 300 %l-703-734-1387 t
amsat-bbs    speed 300 %l-512-852-8194 t
caf        speed 1200 %s8-3406\;
cidemo    speed 1200 set s1 "cis02"; gosub callcis
    pat 1 ID:
    pat 4 "LOGUTL"
    pat 5 "DISCONNECTED"
    pat 2 "please log in: "
    wait
    put 77770,101\r pat 1 assword:; wait
    echo "Sending PASSWORD"; put FREE-DEMO\r
    pat 0 OK; pat 3 tinue; wait
    if "5||2" echo " Login may be possible through a Compuserve Node "
    if "1||4||5||2" echo " Try Again Later "; o; return
    pat;
    pat 1 "menu.!"
    pat 2 "menu!"
    pat 3 "choices.!"
    pat 4 "continue!"
    pat 5 "\n!"
    put \25s\r
    if !fcdemo create cdemo
    wait put "\025g em-49\r"
    wait put \025s\r
    wait put \025off\r
    echo "Good Bye Cruel World"
    close
    o
    gosub review
    return
review    if !fcdemo goto revv1
    kill; read cdemo
    del cut
    display nlmode
    <revv
    review
    wc cut;chek cut;sum cut
    display nonlmode
    return
revv1:    echo "Please run the Compuserve Demo to create the \"cdemo\" file"
    return
cis        speed 1200 nolog 232-4026 sleep 20     : Compuserve via CIS
    put \3
cis:    pat 1 ID:; wait
    put 70001,0001\r pat 1 assword:; wait; put "wrongo\r"
    pat 1 OK; pat 2 Plex!; pat 3 "\nFunction: "; pat 4 "!"
    wait
    if n o return
    pat; t -fcs!p
    return
cis24    speed 2400 nolog 222-2151    : Compuserve via Tymnet 2400 bps
    pat 1i x; wait -f5 put A pat 1 "log in"; wait
    put "cis02;"; goto cis
cis02    speed 1200 nolog 222-0900    : Compuserve via Tymnet
    pat 1i x; wait put A pat 1 "log in"; wait
    put "\030cis02;" goto cis
cisdat    speed 1200 %l-604-687-7144    : Compuserve via Datapac
    sleep 25
    ena -t
    put "..\r"
    pat 1 "DATAPAC"
    wait -f4
    put "P 29400138\r"
    dis -t
    pat 1 "Name:"
    wait -f20
    put "cis\r"
    goto cis
cistel    speed 1200 295-3028        : Compuserve via Telenet
    on !c o abort
    pat 1 TERMINAL
    while !1 put "\r" wait -f1
    pat 1 @
    put "D1\r"; wait -f4
    if !1 o abort
    put "C 202202\r"
    goto cis

navobsy        speed 1200 %l-202-653-1079 t -u7e
    echo " type @tco for list of commands "
nbs        speed 300 %l-301-948-5717 t
nbs2        speed 300 %l-301-948-5718 t
oem        speed 1200 %s8 pat 1i \5;wait;put \1;sb;o
omen-tech    speed 1200 %s8 t
pl24    speed 2400 241-0496 goto pl1    : People-Link via Telenet
pl    speed 1200 295-3028        : People-Link via Telenet
pl1:    patt; patt 1 TERMINAL
    while !1 put "\r" wait -f1
    pf40 patt 1 @
    put "D1\r"; wait
    if !1 o abort
    put "set 0:33,64:1\r"; wait -f1
    put "c 312 63\r"
    pat 1 "PRESS <RETURN>:";  wait -f15;  put "\r"
    pat 1 "ID:";  wait -f15;  put "myacct\r"
    pat 1 "PASSWORD:";  wait -f15;  put "nothis\r"
    set f9 "/next\r"; set f10 "/dlo;fil;xmo;\r\r"
    t
source1200    speed 1200 295-3028    : The Source via Telenet
sourcex:    on !c o abort
    set  f7 "upi n b "
    set  f9 "upi n g "
    set f8 ",-,*,rb"
    set f10 ",-,*,sb"
    pf3
    patt; patt 1 TERMINAL
    while "L<5&&!1" put "\r" wait -f1
    if !1 off
    pf40 patt 1 @
    put "D1\r"; wait
    if !1 o abort
    put "c 30124\r"
    kill; patt; patt 1 SOURCE; wait
    if !1 o abort
    putw "id ABC123 notthis\r"
    patt; pat 10c "-More-" "@put \r lput \r\E[A\E[2M\E[A"
    pf9999; wait
source300    speed 300 295-3028    : The Source via Telenet
    goto sourcex
telegodzilla    speed 1200 %s8-3746
    ena -Z; display overstrike; cls; pat 1 \n
    while "!1&&c&&L<10" put \r wait -f1
    if !1||!c echo "Access Failed"; o; return
    pat 1 "ease:"; wait -f2
    put "\b\b%s6 %s7\r"; pat 1 ect;wait -f2
    put "y"; pat 1 "-Host"; wait -f5
    if !forder putw "\b\bsz demo/order\r"
    set s0 "TeleGodzilla"
tele1:    echo "You are now Online to \42%s0\42."
    echo "Type F1 when done."; t -Z!vn
    lput "\Ez Do you wish to disconnect (y/n) "
    if y echo " Disconnecting ... ";put \25\4; wait -f2; o; return
    echo " **************  Rewinding the Capture Buffer  ************** "
    rewind; wait -vf1; goto tele1

host    echo " host " speed 1200
    set welcome welcome.txt
    set password Ritchie
    set challenge challeng.txt
    set unrestrict "CustomerSupport"    : WARNING - CHANGE THIS!!
    set xhelpfile xyamhelp.t
    set private private; set messages messages
    set emdir "."; set twxfile twx;
    set call2 ATZ\r\336\336ATM1X1S0=1\r\336ATM1X1S0=1\r\336\336
    set outahost "@pk512; putw ATM0H1\r"
    set baudstr "@gosub baud"
    pc40
    return

sinit    pv0;  cls
    echo "    Initial setup for ZCOMM with ZMODEM, WXMODEM, etc.        "
    echo "             I need some phone information.                    "
    accept s6 " Your \E[1mFirst\E[0m name please "
    accept s7 " Your Last name please "
    set s8 ""
getac:    accept s8 " Please enter your 3 digit telephone area code, plus <Enter> "
    if !%s8 goto getac
    echo "I need local access numbers for the Compuserve Information Service."
    if dd lput "Shall I search for them (y/n) ?"
    if dd if y echo "300/1200 bps Access Numbers"; find "%s8 " cisnodes.lst
    echo "Just hit <Enter> if your modem doesn't have the indicated speed."
    accept s3 " Please enter the 1200 baud local Compuserve Node phone Number "
    accept s2 " Please enter the 300 baud local Compuserve Node phone Number "
    accept s5 " Please enter the 1200 baud local Tymnet Node phone Number "
    accept s4 " Please enter the 1200 baud local Telenet Node phone Number "
    echo "Creating disk file 'LOCAL.T' for future reference"
    kill; pv0; create -y local.t
    echof " :Area Code is \042%s8\042"
    if %s2 echof " set s2 \042%s2\042"
    if %s3 echof " set s3 \042%s3\042"
    if %s4 echof " set s4 \042%s4\042"
    if %s5 echof " set s5 \042%s5\042"
    if %s6 echof " set s6 \042%s6\042"
    if %s7 echof " set s7 \042%s7\042"
    echof " set s8 1-503-621"
    lput "\EzAre you using a Color Monitor? (y/n) "
    if y echof " if dd&&dc ps4 pn3 pr97 pu6"; ps4 pn3 pr97 pu6
    lput "\r\nIs your display adapter flicker/snow free? (y/n) "
    if y echof " if dd&&dc display warpdrive"; display warpdrive
    close; echo "file created"
    if dd echo "Searching for directory entries in your area code"
    if dd find l-%s8- %phones
    if dd echo "Please change the lines listed above to suit your area."
    if !is8,503 return
    kill; pv0; create -+ local.t
    lput "Is 621-3746 (Burlington Exchange) a local call for you ? (y/n) "
    if y echof " set s8 621"
    else echof " set s8 1-621"
    close; return
quitt:    echo "   Type 'call demo' for demonstration   "
    if !%f10 quit
    echo "       Press F10 for Flash-Up Help      "
    abort
carrier    lput " Type \ESy\Eq if the modem on port \ET%s9\Eq is now connected to a computer: "
    if y echo "OK, just checking"; sleep 30; set s9 "x"; return
    lput " Is the Modem connected to Port 2 ? "
    if y port 2; if !c lput "\r\n"; set s9 "y"; return
    lput "\r\n\nAlthough ZCOMM can operarte with the modem's\r\n"
    lput "Carrier Detect signal always on, this script (and most other\r\n"
    lput "scripts) require the Carrier Detect signal to read the actual\r\n"
    lput "modem status.  Please adjust the modem accordingly; on the Hayes\r\n"
    lput "SmartModem 1200, switch 6 should be UP. "
    off
xdnum:    cls
    lput "Use 2400 Baud (y/n) ? "
    speed 1200
    if y speed 2400
    lput "Use 300 Baud (y/n) ? "
    if y speed 300
    accept telno "Enter Telephone Number: "
    gosub dial
    sets s0 "%telno"
    goto tele1
glocal:    cls;  display nonlmode
    lput "Use Port 2 (y/n) ?"
    if y port 2
    else port 1
    gosub askspd
    set s0 "Local"
tele9:    echo "You are now Online to %s0."
    echo "Type F1 when done."; t -Z!v
    lput "\Ez Do you wish to disconnect (y/n) "
    if y echo "Be Sure to reset the Modem Port"; gosub ak;  return
    echo " **************  Rewinding the Capture Buffer  ************** "
    rewind; wait -f1; goto tele9
order    if forder display overstrike; page order; return
 cls display overstrike
 lput "ZCOMM Registration, Typeset Manual Pages, SNP, and update disk sells for $40.00.\r\n"
 lput "                 (Add $10 if you wish a PC-size binder)\n"
 lput "\r\n"
 lput "       Send check to Omen Technology, PO Box 4681, Portland OR 97208\r\n"
 lput "\r\n"
 return
baud    pat 1 "CONNECT\r\n"; pat 2 "NO CARRIER"
    pat 5 "CONNECT 1200\r\n"; pat 3 "CONNECT 2400\r\n"
    pe-20
    wait -Ef25
    dis -E
    if 1 speed 300 return
    if 5 speed 1200 sleep 20 return
    if 3 speed 2400 sleep 20 return
    kill create -+ rings
    close
    fail
: This assumes a Hayes compatible modem set for extended result messages
::
:: Alternate dial script for Multi Tech 224 modem uses speed fallback.
:: If the call is placed at > 300 bps, switch to 2400 bps.  Make the
:: call.  If the called modem only supports 1200 or (ugh) 300 bps,
:: the modem will drop back in speed.  The actual connect speed is indicated
:: by a "CONNECT", "CONNECT 1200", or "CONNECT 2400" string.
:: Fallback to 300 bps may be a bit messey, (depending on the answering
:: modem, so a call originated at 300  bps will go out at that speed
::
mm224    pat
    if "%telno<2" echo "Please do not use \"call dial\""; abort
    if "S>301" speed 2400
    : if "S>301" if du speed 1200
    pat 0 K\r\n; ena -d
    if c bye
    put "ATZ\r"; wait -f3; if !0 wait -f3
    put "AT E1 Q0 V1\r"; wait -f3
    if !0 echo "No response From MODEM"; fail
    sleep 4
    put "ATS6=3 X1 S8=1 S0=0\r" wait -f2
    pat 1 "CONNECT\r"; pat 2 "NO CARRIER"; pat 3 "BUSY"; pat 4 RING;
    pat 5 "CONNECT 1200"; pat 0 "CONNECT 2400"
    dis -d
    put %mprefix; put %telno\r
    wait -f60
    while "4&&!L>3" wait -f20
    if 1 speed 300 pat; return
    if 5 speed 1200 pat; return
    if 0 speed 2400 pat; return
    pat; fail